Windows下Tomcat宕机后自动重启Tomcat服务

如何在Windows服务器上创建一个bat脚本，通过curl工具监测Tomcat服务的状态。当Tomcat无故宕机时，脚本会自动重启服务。首先，需要安装curl环境，然后设置脚本，包括定义URL、Tomcat路径、启动和关闭命令等，通过循环检测HTT P状态码来判断服务是否正常，异常时执行重启操作。

一、问题描述及解决原理

把项目发布到windows服务器中，如tomcat工程不稳定，会有无故宕机的问题。如果通过程序无法解决，并且重启tomcat服务能够生效的话，可以做一个自动检测并重启的脚本。

脚本通过检测tomcat对应的工程链接（http或者https）是否已经正常启动，如果未正常启动，则重启tomcat服务。

二、安装curl环境

1、curl介绍

curl（全称Client URL）：用于在命令行下运行的网络工具，用于与服务器进行通信。它支持多种协议，支持DICT, FILE, FTP, FTPS, Gopher, HTTP, HTTPS, IMAP, IMAPS, LDAP, LDAPS, POP3, POP3S, RTMP, RTSP, SCP, SFTP, SMB, SMBS, SMTP, SMTPS, Telnet and TFTP。 curl 支持SSL证书, HTTP POST, HTTP PUT, FTP上传, 基于HTTP表单的上传, 代理, HTTP/2, cookies, 用户+密码认证 (Basic, Plain, Digest, CRAM-MD5, NTLM, Negotiate and Kerberos), 文件传输修复, 隧道代理等等。

2、官网网站：https://curl.se/download.html

3、配置步骤

（1）下翻找到windwos版本，点击最新对应版本下载，我下载的是64位的

（2）点击进入后，下载对应架构的包。（比如我的是x86，就下载第一个）

（3）解压下载的压缩包，并将解压后的放在某个目录下

（5）打开命令行窗口验证，如下即成功。（命令行要打开一个新的）

三、bat脚本

@echo off
setlocal enabledelayedexpansion

rem 链接
set URL="http://localhost:8080"
rem tomcat目录
set TOMCAT_HOME="E:\HMMJabTY\Tomcat8"
rem 关闭tomcat命令的路径
set CLOSE_CMD=%TOMCAT_HOME%\bin\shutdown.bat
rem 启动tomcat命令的路径
set START_CMD=%TOMCAT_HOME%\bin\start.bat
rem tomcat缓存目录
set TOMCAT_CACHE=%TOMCAT_HOME%\work
rem 日志文件的路径
set LOG_PATH=%TOMCAT_HOME%\check.log
rem 每次检测完后等待时间，再进行下一次检测，秒，若将程序部署到系统计划任务，可忽略
set TIME_WAIT=5

:loop
set httpcode=0
cd /d %TOMCAT_HOME%
echo %date% %time%
echo 'begin checking tomcat'

echo %date% %time% >>%LOG_PATH%
for /l %%i in (1,1,3) do (
 echo %%i
 for /f "delims=" %%r in ('curl -sL -w "%%{http_code}" %URL% -o /dev/null') do (
  set httpcode=%%r
  if !httpcode!==200 (
   GOTO :OUTFOR
  )
 )
)

:OUTFOR
echo %httpcode% >>%LOG_PATH%

if not %httpcode%==200 (
 echo close tomcat >>%LOG_PATH%
 call %CLOSE_CMD%
 timeout -t 5 >nul
 echo success to close tomcat >>%LOG_PATH%

 rd /S /Q %TOMCAT_CACHE%
 echo start tomcat >>%LOG_PATH%
 call %START_CMD%
 
 echo success to start tomcat
 echo success to start tomcat >>%LOG_PATH%
) else (
 echo the tomcat run is ok
 echo the tomcat run is ok >>%LOG_PATH%
)
timeout -t 3 >nul
rem 若将脚本程序部署到系统计划程序中，将以下代码可注释
timeout -t %TIME_WAIT% >nul
goto loop

四、扩展：脚本解析

脚本逻辑：该脚本会自动检测tomcat启动成功后的一个地址，（就是你tomcat启动成功后能访问的一个地址，你可以写一个测试地址，比如我这里是http://localhost:8080/），如果访问不到就会自动启动tomcat的start.bat文件

@echo off
# 在此语句后所有运行的命令都不显示命令行本身，但是本身的指令是会显示出来的

setlocal enabledelayedexpansion
# 先了解一下批处理运行命令的机制：批处理读取命令时是按行读取的（另外例如for命令等，其后用一对圆括号闭合的所有语句也当作一行），在处理之前要完成必要的预处理工作，这其中就包括对该行命令中的变量赋值。
# 此语句含义：本地延迟扩展。延迟变量，全程延迟环境变量扩展。即不是先给该行变量赋值，而是在运行过程中给变量赋值。

rem 链接
# rem在bat脚本中为注释，执行脚本时会忽略此语句

set URL="https://localhost:8080"
# set指令用来设置变量

rem tomcat目录
set TOMCAT_HOME="E:\HMMJabTY\Tomcat8"
rem 关闭tomcat命令的路径
set CLOSE_CMD=%TOMCAT_HOME%\bin\shutdown.bat
rem 启动tomcat命令的路径
set START_CMD=%TOMCAT_HOME%\bin\start.bat
rem tomcat缓存目录
set TOMCAT_CACHE=%TOMCAT_HOME%\work
rem 日志文件的路径
set LOG_PATH=%TOMCAT_HOME%\check.log
rem 每次检测完后等待时间，再进行下一次检测，秒，若将程序部署到系统计划任务，可忽略
set TIME_WAIT=5

:loop
# 在Bat中有标签一词，跟C语言的函数类似。并且标签必须单独一行，并且以冒号开头。

set httpcode=0
cd /d %TOMCAT_HOME%
echo %date% %time%
echo 'begin checking tomcat'

echo %date% %time% >>%LOG_PATH%
# >>追加内容到文件末尾，而不会清除原有的内容主要将本来显示在屏幕上的内容输出到指定文件中指定文件如果不存在，则自动生成该文件


# 循环指令。这里需要了解两个关键字%i、%%i。%i这个关键字不能在bat中使用。只能再CMD命令下的for中使用，%%i是在bat的for中使用的指令。
# 规则：for、in和do是for语句的关键字，它们三个缺一不可。
# /l:表示以增量形式从开始到结束的一个数字序列
# (1,1,3):跟参数/l配合使用时，表示从1开始，以1递增，直到3。这就是循环3次。
# /f：主要用来处理文件和一些命令的输出结果。它可以提取文本文件的内容，进行逐行分析和处理
# delims=符号列表：切分字符串。没有指定符号则for /f语句以空格键或跳格键作为分隔符；如果制定了如“delims=,.”，则以逗号和句号作为被处理的字符串的分隔符号。

# curl:
# -s: 静默模式，在命令行中不会输出无关中间过程信息
# -L：自动重定向，有的网址是自动跳转的。使用-L参数，curl就会跳转到新的网址。
# -k：在发送https请求时，加上-k参数，否则会有如下证书的报错。如果是http请求，可以不加。
# -o：将返回内容输出到文件中。其中nul相当于linux中的/dev/null。功能就是一种特殊的虚拟设备，用于写入而不是读取。写入/dev/null的任何内容都会从操作系统中消失。
# -w：操作完成后在返回信息尾部追加指定的内容。完成请求传输后，使 curl 在 stdout 上显示自定义信息。%%{http_code}为返回的状态码。（状态码文档末尾有各种码值的解释）


for /l %%i in (1,1,3) do (
 echo %%i
 for /f "delims=" %%r in ('curl -sL -k %URL% -o nul -w "%%{http_code}"' ) do (
  set httpcode=%%r
  if !httpcode!==200 (
   GOTO :OUTFOR
  )
 )
)

:OUTFOR
echo %httpcode% >>%LOG_PATH%

# call：使用call命令，可以调用其它程序（包括批处理文件、其它执行命令）或标签。
# timeout -t 5:延时5s操作。>nul作用为屏幕不提示

if not %httpcode%==200 (
 echo close tomcat >>%LOG_PATH%
 call %CLOSE_CMD%
 timeout -t 5 >nul
 echo success to close tomcat >>%LOG_PATH%

# /S：表示除目录本身外，还将删除指定目录下的所有子目录和文件。用于删除目录树。
# /Q：安静模式，带/S 删除目录树时不要求确认。
 rd /S /Q %TOMCAT_CACHE%
 echo start tomcat >>%LOG_PATH%
 call %START_CMD%
 
 echo success to start tomcat
 echo success to start tomcat >>%LOG_PATH%
) else (
 echo the tomcat run is ok
 echo the tomcat run is ok >>%LOG_PATH%
)
timeout -t 3 >nul
rem 若将脚本程序部署到系统计划程序中，将以下代码可注释
timeout -t %TIME_WAIT% >nul
goto loop

使用tomcat8w启动

上述脚本是让tomcat使用cmd窗口启动，如果想用tomcat8w启动，如下图，则将脚本做微调可实现。

（1）编写restart.bat脚本

新建一个文件restart.bat，将以下脚本放在里边，并放到tomcat/bin目录下。

@echo off
net start tomcat8w

（2）修改START_CMD参数

将上述的启动tomcat命令的路径，start_cmd改为restart.bat